***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 23, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PEC3836C2A-AU 1 2
.param
+vc0 = 1.21e-11	 vc1 = 1.68e-11   	 vc2 = 6.58e-1	vc3 = 1.814e-12	 vc4 = 3.24e-2
+tc1 = 2.08e-2		 tc2 = 6.61e-3		 tc3 = 6.01e-3		 tc4 = 6.531e-2 
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 1 C zener
g1 C 1 value = {irexp(v(C,1))}
d2 2 C zener
g2 C 2 value = {irexp(v(C,2))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 1e-15		   n = 1		  rs = 1.137e-1
+ibv = 1e-3		 nbv = 1e-3		  bv = 44.3
***** capacitance parameter *****
+cjo = 1.33e-11	   m = 1.613e-1		  vj = 1.405 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 0.75		 xti = 3
+trs1 = 1e-3		tbv1 = 8.287e-4  tbv2 = -9.35e-7
.ends PEC3836C2A-AU
*$
